// Persistence Of Vision Ray Tracer Scene Description File
// -------------------------------------------------------
// File: @(#)signature.pov
// Description: signature image with alpha channel
// Creation Date: $ 15 Sep 2004, 23:33:05 $
// Last modified: $ 16 Sep 2004, 10:26:26 $
// Author: Christoph Hormann
//
// -w1280 -h960 +a0.1 +am2 +r5 +fn +ua
//

#version 3.6;

global_settings {
	assumed_gamma 1
}

camera {
	orthographic
	location <0,0,-1>
	look_at  <0,0,0>
	right (4/3)*x
	up 1*y
}

light_source {
	<5,5,-50>
	color rgb 1.3
}

sphere {
	0, 1
	pigment {
		gradient z
		color_map {
			[0.0 rgb <0.6,0.7,1.0>]
			[0.7 rgb <0.0,0.1,0.8>]
		}
	}
	scale 1000
	no_image
}

// ----------------------------------------

#declare fn_Pig_Text=
	function {
		pigment {
			object {
				text {
					ttf "crystal.ttf"
					"Copyright POV-Team, September 2004",
					1, 0
				}
				color rgb 0.1
				color rgb 0.95
			}
			scale 0.025
			translate <0.1,0.1,-0.01>
	
		}
	}

#include "functions.inc"

#declare Sig=
	height_field {
		function 1000, 200 { fn_Pig_Text(x,y/5,0).red /*- f_noise3d(x*50, y*50, 0)*0.03*/  }
		water_level 0.5
		smooth
		rotate 90*x
		scale <1, 0.2, 0.1>
		translate <0.112, -0.39, 0>
	}

object {
	Sig
	texture {
		pigment { color rgb 0.5 }
		finish {
			ambient 0.05
			diffuse 0.5
			specular 0.5
			roughness 0.1
			reflection 1
		}
	}
}

object {
	Sig
	translate <0.002, -0.002, 0.05>
	texture {
		pigment { color rgb 0.1 }
		finish {
			ambient 0.05
		}
	}
}